IRCForumu.Net | Türkiye'nin IRCd ve mIRC Forumu   Reklam Alanı


  IRCForumu.Net | Türkiye'nin IRCd ve mIRC Forumu IF - mIRC Scripting mIRC ve Socket Botlar

Reklam alanı

Like Tree1Beğeni(ler)
  • 1 Post By immortaL
Yeni Konu   Cevap Yaz

 
LinkBack Seçenekler Stil
Alt 05 Nisan 2019, 00:04   #1
 
Üyelik tarihi: 07 Mayıs 2016
Bulunduğu yer: Ankara
Mesajlar: 579
WEB Sitesi: www.Sohbetsin.Com
IRC Sunucusu: irc.FixSohbet.Net
İlgi Alanı: Domain
Kan Grubu: A RH (+)
Alınan Beğeni: 81
Post IGS v1.0 [Web AUTH]

Merhaba,
Sunucuya girişte proxy olarak tespit edilen kişilere doğrulama sağlaması için web auth linki verilir ve 1 dakika içerisinde doğrulama yapması istenilir, doğrulama yapan kullanıcıları üzerindeki engelleme kaldırılır ve kanallara aktarır, doğrulama yapmayan kullanıcıları ise sunucudan uzaklaştırılır.

Kod:
alias _pbot return IGS
alias _pass return 123321
alias _ident return Paradox
alias _username return 4Coder By Toprak
alias _oper return IGS 123321
alias _supass return 123321
alias _sunucu return irc.Toprak.NET
alias _sunucuip return 185.50.68.120
alias _port return 6667
alias _opers return #Opers

;- Ayarlar.php'de "$port" ile aynı olsun
alias _igsport return 1990

;- Ayarlar.php'de "$esifre" ile aynı olsun
alias _igsifre return eklesifresibelirtiniz

alias bagla sockopen pbot $_sunucuip $_port
alias swpbot $iif($sock(pbot).status == active,sockwrite -nt pbot $1-)
on *:sockclose:pbot:$+(.timer,_saatkontrol) 1 2 bagla
on *:sockopen:pbot:{
  if ($sockerr) { sockclose pbot | $+(.timer,_saatkontrol) 1 2 bagla | returnex }
  swpbot NICK $+($_pbot,$r(10,9999)) 
  swpbot USER $_ident "" " $+ $iif($host,$host,$ip) $_username
  sockmark $sockname $_pbot
}
on *:sockread:pbot:{
  if ($sockerr) { sockclose pbot | $+(.timer,_saatkontrol) 1 2 bagla | returnex }
  var %;pbot | sockread %;pbot | tokenize 32 %;pbot
  if ($1 = ping) swpbot pong $remove($2,:) 
  elseif $regex($2,/(001|433)/) { swpbot oper $_oper | swpbot ns ghost $_pbot $_pass | swpbot ns release $_pbot $_pass | swpbot join #0,0 | $+(.timer,$rand(100,999)) 1 3 swpbot nick $_pbot }
  elseif $1 == error && $2 == :closing { sockclose pbot | $+(.timer,_saatkontrol) 1 2 bagla }  
  elseif $regex($2,/(473|475|471|474)/) { swpbot sajoin $_pbot $4 }
  elseif $regex($2,/(481|411)/) { swpbot oper $_oper | swpbot nick $_pbot | swpbot nickserv identify $_pass }
  elseif ($2 == NICK) { 
    if $_nick($1) == $_pbot { swpbot ns ghost $_pbot $_pass | swpbot ns release $_pbot $_pass | $+(.timer,$rand(100,999)) 1 3 swpbot nick $_pbot }
    elseif $right($3,-1) == $_pbot {
      swpbot nickserv identify $_pass      
      swpbot oper $_oper
      $iif($_supass,swpbot os su $_supass)
      swpbot join #0,0
      swpbot mode $right($3,-1) +qHp-h
      $+(.timer,_pbgir) 1 5 swpbot sajoin $right($3,-1) $_opers
      $iif(!$sock(igs),socklisten igs $_igsport)
    }
  }
  elseif $regex($2,/366/) && !$istok($_opers,$4,32) { swpbot part $4 }  
  elseif $regex($2,/^PART$/i) {
    if $regex($_nick($1),/ $+ $+(^,$_pbot,$) $+ /Si) && $istok($_opers,$3,32) { swpbot sajoin $_nick($1) $3 }
  }
  elseif $regex($2,/^KICK$/i) {
    if $regex($4,/ $+ $+(^,$_pbot,$) $+ /Si) && $istok($_opers,$3,32) { swpbot sajoin $4 $3 }
  }
  elseif $regex($2,/^JOIN$/i) {
    if $regex($_nick($1),/ $+ $+(^,$_pbot,$) $+ /Si) && $istok($_opers,$right($3,-1),32) {
      swpbot mode $right($3,-1) -qao+h $str($+($_nick($1),$chr(32)),5)
      swpbot mode $_nick($1) +qHp-h
      $iif(!$sock(igs),socklisten igs $_igsport)
    }
  }
  elseif $regex($2,/^MODE$/Si) && $regex($3,/^#/) {
    if $regex($4,^\+(\S+)?(b)(\S+)?) && $regex($5,/^ $+ $_pbot $+ /i) { swpbot mode $3 -b $_pbot }
    elseif $regex($4,^\-(\S+)?(h)(\S+)?) || $regex($4,^\+(\S+)?(a|q|o)(\S+)?) && $regex($5-,/ $+ $_pbot $+ /i) { swpbot mode $3 -qao+h $str($+($_pbot,$chr(32)),5) }
  }
  elseif $regex($2,/^NOTICE$/Si) && !$regex($1,/(\@)/i) {
    if $regex($4-,/(Kullanıcı ba[gqğĞ]landı|Client connecting on)/Si) {
      var %:_n $token($token($4-,1,40),-1,32), %:_ip $token($token($4-,2,64),1,41), %:_port $token($token($4-,1,58),-1,32)
      if $istok($_sunucuip %:myip,%:_ip,32) { return }
      else { 
        swpbot notice %:_n 5***
        swpbot notice %:_n 5*** 2Guvenlik taramalarindan geciriliyorsunuz. Lutfen bekleyiniz.
        swpbot notice %:_n 5***
        swpbot who +I %:_n 
      }
    }
  }
  elseif $regex($2,/352/) {
    var %:wnick $8, %:wip $6, %_p $+(%:wnick,$r(100,9999999)) 
    if !$hget(IGS-Muaf,$6) {
      sockopen $+(proxy-kontrol,%_p) proxy.teklan.com.tr 80 
      sockmark $+(proxy-kontrol,%_p) $+(%:wip,¿,%:wnick) 
    }
    else {
      _dagit %:wnick
      swpbot privmsg $_opers $+(:4,%:wnick,) nick'i güvenlik doğrulamasını geçti ve global kanallara alındı. 
    }
  }
}
on *:sockopen:proxy-kontrol*:{ 
  if ($sockerr) { .sockclose $sockname | return }
  sockwrite -nt $sockname GET $+(/?ip=,$token($sock($sockname).mark,1,191))  HTTP/1.1 
  sockwrite -nt $sockname Host: $sock($sockname).addr
  sockwrite -nt $sockname Accept: image/jpeg, application/x-ms-application, image/gif, application/xaml+xml, image/pjpeg, application/x-ms-xbap, */*
  sockwrite -nt $sockname Accept-Language: tr-TR
  sockwrite -nt $sockname User-Agent: Mozilla/4.0 (compatible; MSIE 8.0; Windows NT 6.1; Trident/4.0; SLCC2; .NET CLR 2.0.50727; .NET CLR 3.5.30729; .NET CLR 3.0.30729)
  sockwrite -nt $sockname Connection: Keep-Alive
  sockwrite -nt $sockname $crlf
}
on *:sockread:proxy-kontrol*:{ 
  if ($sockerr) { .sockclose $sockname | return }
  var %:pkr | sockread -f %:pkr | tokenize 32 %:pkr
  if $regex($1-,/numaral[ıiİ] [Iİi]P proxy\'d[ıiİ]r/i) {
    _proxy-ok $token($sock($sockname).mark,2,191) $token($sock($sockname).mark,1,191) 
    sockclose $sockname
  }
  elseif $regex($1-,/numaral[ıiİ] [Iİi]P proxy de[qgğĞ][ıiİ]ld[ıiİ]r/i) {
    if !$regex($1-,/T[uüÜ]rkey/Si) { _proxy-ok $token($sock($sockname).mark,2,191) $token($sock($sockname).mark,1,191) | sockclose $sockname }
    else { _dagit $token($sock($sockname).mark,2,191) | sockclose $sockname }
  }
}
alias _proxy-ok {
  var %:_r $+($1,$r(100,9999999)), %_l $+(http://igs.,$lower($gettok($_sunucu,2-,46)),/index.php?auth=,$left($md5($1),5))
  swpbot notice $1 :2Lütfen girişinizi onaylamak için5 1 dakika 2içinde aşağıdaki linke tıklayınız.
  swpbot notice $1 :2Girişinizi onaylamazsanız sunucuya girişiniz engellenecektir.
  swpbot notice $1 :2Giriş için tıklayınız:3 %_l
  sockopen $+(syekle,%:_r) $+(igs.,$gettok($_sunucu,2-,46)) 80 | sockmark $+(syekle,%:_r) $+($2,¿,ekle)
  $+(.timer,$2,xline) 1 65 _ban-at $2
}
alias _ban-at {
  swpbot gline $+(*@,$1) +1h 4WEB AUTH kodunu girmediniz..
  var %:_r $+($1,$r(100,9999999))
  sockopen $+(syekle,%:_r) $+(igs.,$gettok($_sunucu,2-,46)) 80 | sockmark $+(syekle,%:_r) $+($1,¿,sil)
}
alias _dagit {
  swpbot notice $1 5*** 3Taramalardan basariyla gectiniz. Kanallara aktariliyorsunuz.
  $+(.timer,gec,$1) 1 2 swpbot gec $1
}

on *:sockopen:syekle*:{ 
  if ($sockerr) { .sockclose $sockname | return }
  sockwrite -nt $sockname GET $+(/ekles.php?durum=,$token($sock($sockname).mark,2,191),&ip=,$token($sock($sockname).mark,1,191),&sifre=,$_igsifre)  HTTP/1.1 
  sockwrite -nt $sockname Host: $sock($sockname).addr
  sockwrite -nt $sockname Accept: image/jpeg, application/x-ms-application, image/gif, application/xaml+xml, image/pjpeg, application/x-ms-xbap, */*
  sockwrite -nt $sockname Accept-Language: tr-TR
  sockwrite -nt $sockname User-Agent: Mozilla/4.0 (compatible; MSIE 8.0; Windows NT 6.1; Trident/4.0; SLCC2; .NET CLR 2.0.50727; .NET CLR 3.5.30729; .NET CLR 3.0.30729)
  sockwrite -nt $sockname Connection: Keep-Alive
  sockwrite -nt $sockname $crlf
}
alias sw $iif($sock($1),sockwrite -nt $1-)
on *:socklisten:igs:{ var %:sockname $+(igs-,$md5($ticks,$rand(a,Z))) | if !$sock(%:sockname) { .sockaccept %:sockname } }
on *:sockread:igs-*:{
  var %:igs | sockread -f %:igs | tokenize 32 %:igs
  if $regex($1,/^\[IGS\]/Si) {
    $+(.timer,$token($1,2,62),xline) off
    .hadd -msu10000 IGS-Muaf $token($1,2,62) oke.
    swpbot who +h $token($1,2,62)
    sockclose $sockname
  }
}

Not: Ana bottan ayırıp paylaştım bir sorun yada yardım lazım olur ise PM atmanız yeterli..
DipNot: BURADAKI modul'e göre ayarlıdır..


IGS PHP KLASORU
IRCoder bunu beğendi.





 immortaL isimli Üye şimdilik offline konumundadır   Alıntı
Alt 07 Ekim 2019, 21:51   #2
 
Üyelik tarihi: 15 Temmuz 2017
Bulunduğu yer: Adana
Mesajlar: 2
WEB Sitesi: http://ww.ircoder.org
IRC Sunucusu: irc.soyle.net
İlgi Alanı: Yok
Kan Grubu: 0 RH (-)
Alınan Beğeni: 0
Standart Cevap: IGS v1.0 [Web AUTH]

Ziyaretçilere içerik gizlenmiştir.
Ücretsiz olarak sizde bize katılmak istermisiniz?

Kayıt ol Giriş yap

 IRCoder isimli Üye şimdilik offline konumundadır   Alıntı

Yeni Konu   Cevap Yaz

Etiketler
auth, igs, v10, web

Seçenekler
Stil

Yetkileriniz
Konu Acma Yetkiniz Yok
Cevap Yazma Yetkiniz Yok
Eklenti Yükleme Yetkiniz Yok
Mesajınızı Değiştirme Yetkiniz Yok

BB code is Açık
Smileler Açık
[IMG] Kodları Açık
HTML-Kodu Kapalı
Trackbacks are Açık
Pingbacks are Açık
Refbacks are Açık



Tüm Zamanlar GMT +3 Olarak Ayarlanmış. Şuanki Zaman: 19:59.


Powered by vBulletin® Version 3.8.9 Beta 1
Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.
Search Engine Friendly URLs by vBSEO 3.6.0
IRCForumu - Sohbet
Copyright ©2005 - 2016 IRCForumu.Net | Tüm Hakları Saklıdır.