IRCForumu.Net - Türkiye'nin IRC ve mIRC Kullanıcılarının Buluştuğu Forum

on :dialog::::

-

DIALOG, dialog(lar) içerisinde yapılan tüm işlemleri algılayan olaydır.
Bu konu biraz daha geniş bir konudur. Dialoglar hakkında bilgiye sahip değilseniz, dersler bölümünde ilgili dersi bulup okumanız önerilir.
-
Event içerisinde kullanılabilen identifier-lar;
a- $dname (dialog ismini veren identifier)
b- $devent (dialog içerisindeki event(olay) ismini veren identifier)
c- $did (dialog içerisindeki işlem gören yapının id numarasını veren identifier)
-
Örnek:
Aşağıdaki kodları remote-a entegre ediniz. Ve "/dialog -md deneme deneme" yazınız.
Ardından, dialog üzerinde belirli noktalara kafanıza göre tıklayınız. Dialog-u kapatınız, sonra açınız vs.
Yani kısacası dialog üzerinde mouse ile oynayıp neyin ne işe yaradığını anlayınız. Bu arada event içerisindeki kodlarıda inceleyin.
Gayet basittir.

-

Kod:

dialog deneme {

  title "Örnek Dialog"

  size -1 -1 136 165

  option dbu

  button "Button - Tuş", 1, 3 9 56 12

  edit "Editbox - Yazı kutusu", 2, 3 25 57 10

  text "Sadece yazı noktası", 3, 4 37 55 8, center

  combo 4, 3 49 57 50, size

  box "Group Box - Grup Kutusu", 5, 63 6 70 50

  list 6, 63 57 69 40, size

  check "Check Box - İşaretleme Kutusu", 7, 3 100 87 10

  radio "Radio Button - Radio tarzı tuş", 8, 3 110 86 10

  link "Hyperlink - Link yazısı(internet vs.)", 9, 3 121 88 8

  icon 10, 92 101 37 26, C:\Users\Gold PC\Desktop\L4\RESIMLER\AILE\Adsız.jpg, 0, noborder

  tab "Tab 1", 11, 3 131 99 38

  scroll "Scroll", 12, 115 134 8 37, top

  menu "Item1", 13

  item "Item7", 19, 13

  menu "Item2", 14

  item "Item8", 20, 14

  menu "Item3", 15

  item "Item9", 21, 15

  menu "Item4", 16

  item "Item10", 22, 16

  menu "Item5", 17

  item "Item11", 23, 17

  menu "Item6", 18

  item "Item12", 24, 18

}

on *:dialog:*:*:*: {

  if ($dname = deneme) {

    ;EĞER DİALOG İSMİ DENEME İSE, AŞAĞIDAKİLERİ YAP!

    if ($devent = init)  { 

      did -a $dname 4,6 BU BİR DENEME. 

      echo -: EVENT(OLAY) INIT(ALGILAMA) 

    }

    if ($devent = close) echo -: EVENT(OLAY) CLOSE(DIALOG KAPATILIRSA)

    if ($devent = edit) echo -: EVENT(OLAY) EDIT(HERHANGİ BİR EDITBOX-A VEYA COMBO-BOX-IN EDITBOX-INDA YAPILAN İŞLEV)

    if ($devent = sclick) { 

      if ($did = 1) echo 4 -: 1 numaralı button(tuş)a tıklandı.

      if ($did = 7) echo 4 -: 7 numaralı check-box(işaretleme tuşun)a tıklandı.

      if ($did = 8) echo 4 -: 8 numaralı radio buttonun(radyo tuşun)a tıklandı.

      if ($did = 4) echo 4 -: 4 numaralı combo-box-a tıklandı.

      if ($did = 6) echo 4 -: 6 numaralı list-box(liste kutusun)a tıklandı.

      if ($did = 9) echo 4 -: 9 numaralı hyperlink(link)e tıklandı.

      echo -: EVENT(OLAY) SCLICK(SOL TIKLAMA)

    }

    if ($devent = dclick) echo -: EVENT(OLAY) DCLICK(ÇİFT TIKLAMA)

    if ($devent = menu) echo -: EVENT(OLAY) MENU(HERHANGİ BİR MENU PARÇASI İŞLEVİNDE)

    if ($devent = scroll) echo -: EVENT(OLAY) SCROLL(HERHANGİ BİR SCROLL KONTROL İŞLEVİNDE)

    if ($devent = mouse) echo -: EVENT(OLAY) MOUSE(MOUSE HARAKETİNİ ALGILAR) - $MOUSE.X - $MOUSE.Y 

    if ($devent = uclick) echo -: EVENT(OLAY) UCLICK(SOL TIK SERBEST BIRAKILDIĞINDA)

    if ($devent = rclick) echo -: EVENT(OLAY) RCLICK(SAĞ TIKLAMA)

    if ($devent = drop) echo -: EVENT(OLAY) DROP(SOL TIKLAMA YAPILIP, TIKLAMA YAPILAN KORDİNATTAN FARKLI BİR KORDİNATTA SERBEST BIRAKILDIĞINDA)

  }

}